--------------------------------------------------------------------------------------
**	Defintion of implemented grammar of Delta defined in EBNF
**	** Correct as of: 4/9/2008 **
**
**	"xxx"			- Terminal
**	<yyy>			- Non-terminal
**
**	Parentheses, ()		- Grouping
**	Vertical bar, |		- Alternation
**	Square brackets, []	- Optional
**
**	Kleene star, *		- Repeat 0 or more times
**	Kneene plus, +		- Repeat 1 or more times
--------------------------------------------------------------------------------------

--------------------------------------------------------------------------------------
TOP LEVEL COMMANDS


<top level command> ::=	( "library" <library commands> | <query> | "exit" ) ";"


<query> ::=		"boolean query" <delta-formula> | "set query" <delta-term>


--------------------------------------------------------------------------------------
LIBRARY COMMANDS


<library commands> ::=	"add" <declarations> |
			"list" [ "verbose" ]


--------------------------------------------------------------------------------------
DECLARATIONS


<declarations> ::=	<declaration> ( "," <declaration> )*
<declaration> ::= 	<set constant declaration> | <label constant declaration> |
			<set query declaration> | <boolean query declaration>

<set constant declaration> ::=		"set constant" <set constant> ("be"|"=") <delta-term>
<label constant declaration> ::=	"label constant" <label constant> ("be"|"=") <label value>
<set query declaration> ::=		"set query" <set query name> "(" <variables> ")" ("be"|"=") <delta-term>
<boolean query declaration> ::=		"boolean query" <boolean query name> "(" <variables> ")" ("be"|"=") <delta-formula>

<variables> ::=		<variable> ( "," <variable> )*
<variable> ::=		( "set" <set variable> | "label" <label variable> )

<parameters> ::=	<parameter> ( "," <parameter> )*
<parameter> ::=		( <delta-term> | <label> )

<boolean query name> ::=	<identifier>
<set query name> ::=		<identifier>


--------------------------------------------------------------------------------------
DELTA-TERMS


<delta-term> ::=	<set variable> |
			<set constant> |
			<set name> |
			<atomic value> |
			<enumerate> | 
			<union> | 
			"(" <multiple union> ")" | 
			<collect> | 
			<separate> |
			<transitive closure> | 
			<recursion> | 
			<decoration> | 
			<if-else term> | 
			<set query call> | 
			<delta-term with declarations>


<set name> ::=		<URI> "#" <simple set name>

<atomic value> ::=	""" <identifier> """

<enumerate> ::=		"{" <labelled terms> "}"

<union> ::=		( "U" | "union" ) <delta-term>

<multiple union> ::=	<delta-term> ( ( "U" | "union" ) <multiple union> )*

<collect> ::=		"collect" "{" <labelled term> ( "where" | "|" ) <variable pair> ("in"|"<-") <delta-term> [ "and" <delta-formula> ] "}"

<separate> ::=		"separate" "{" <variable pair> ("in"|"<-") <delta-term> ( "where" | "|" ) <delta-formula> "}"

<transitive closure> ::= ( "tc" | "TC" | "transitiveclosure" ) <delta-term>

<recursion> ::=		"recursion " <set variable> " {" <variable pair> (" in "| "<- ") <delta-term> ( "where" | "|" ) <delta-formula> "}"

<decoration> ::=	"decorate" "(" <delta-term> ", " <delta-term> ")"

<if-else term> ::=	"if" <delta-formula> "then" <delta-term> "else" <delta-term> "fi"

<set query call> ::=	"call" <set query name> "(" <parameters> ")"

<delta-term with declarations> ::= "let " <declarations> "in"  <delta-term> " endlet"


<URI> ::= 		( <web prefix> | <local prefix> ) <file path>
<web prefix> ::=		"http://" <host> "/" [ "~" <identifier> "/" ]
<local prefix> ::=	"file://" ( (A-Z) | (a-z) ) ":/"
<host> ::=		<identifier> [ "." <host> ]
<file path> ::=		<identifier> ( "/" <file path> | <extension> )
<extension> ::=		".xml"
<simple set name> ::=	<identifier>


--------------------------------------------------------------------------------------
DELTA-FORMULAS


<delta-formula> ::=	<atomic formula> | 
			<if-else formula> | 
			<delta-formula with declarations>
			"(" <conjunction> ")" |
			"(" <disjunction> ")" |
			"(" <quasi-implication> ")" |
			<quantified formula> |
			<negated formula>


<atomic formula> ::=	<equality> | <label relationship> | <membership> | <boolean query call> | "true" | "false"

<equality> ::=		<set equality> | <label equality>

<set equality> ::=	<delta-term> "=" <delta-term>

<label equality> ::=	<label> "=" <wildcard label> | <wildcard label>  "=" <label>

<wildcard label> ::=	["*"] ( <label variable> | <label constant> ) ["*"] |		
			"'" ["*"] <identifier> ["*"] "'"

<label relationship> ::= <label> "<" <label>
			<label> ">" <label>
			<label> "<=" <label>
			<label> ">=" <label>

<membership> ::=	<labelled term> ("in"|"<-") <delta-term>

<boolean query call> ::= "call" <boolean query name> "(" <parameters> ")"

<if-else formula> ::=	"if" <delta-formula> "then" <delta-formula> "else" <delta-formula> "fi"

<delta-formula with declarations> ::= "let " <declarations> "in"  <delta-formula> " endlet"

<conjunction> ::=	<delta-formula> ( "and" <delta-formula> )*

<disjunction> ::=	<delta-formula> ( "or"  <delta-formula> )*

<quasi-implication> ::=	<delta-formula> ( <quasi-implication connective> <delta-formula> )*
<quasi-implication connective> ::= "<=" | "=>" | "implies" | "iff" | "<=>"

<quantified formula> ::= <forall> <delta-formula> | <exists> <delta-formula>

<forall> ::=		"forall" <variable pair> ("in"|"<-") <delta-term> [ "." ]
<exists> ::=		"exists" <variable pair> ("in"|"<-") <delta-term> [ "." ]

<negated formula> ::= 	"not" <delta-formula>


--------------------------------------------------------------------------------------
VARIABLES, CONSTANTS, etc.


<label> ::=		<label variable> | <label value> | <label constant>
<label variable> ::=	<identifier>
<label constant> ::=	<identifier>
<label value> ::=	"'" <identifier> "'"

<set variable> ::=	<identifier>
<set constant> ::=	<identifier>

<labelled terms> ::=	<labelled term> ( "," <labelled term> )*
<labelled term> ::=	<label> ":" <delta-term>

<variable pair> ::=	<variable pair label> ":" <variable pair term>
<variable pair label> ::= <label variable> | <label value>
<variable pair term> ::= <set variable>

<identifier> ::=	( (A-Z) | (a-z) | (0-9) | "_" | "-" )+